Taylor Series Model

S[x_]=Normal[Series[f[x],{x,c,4}]] (*Taylor Series expansion*)

S[((a+b)/2)] (*Example*)

Definite Integral of Taylor Series

Exact=Simplify[Integrate[S[x],{x,a,b}]] (*Exact integral of S(x) on [a,b]*)

Midpoint Integration

Midpoint = Simplify[(b-a)S[((a+b)/2)]]

Midpoint-Exact

Trapezoid Integration

Trap=Simplify[(b-a)((S[a]+S[b])/2)] (*Series expansion of trapezoid rule about c*)

Trap-Exact

(*How does this compare to Midpoint??*)

Simpson Rule

Simp=FullSimplify[(((b-a))/6)(S[a]+4S[((a+b)/2)]+S[b])]

Simp-Exact

Finite Differences

FwdDiff=Simplify[((S[c+h]-S[c])/h)]

CenteredDiff=Simplify[((S[c+h]-S[c-h])/(2h))]

CenteredDiff2nd = Simplify[((S[c+h]-2S[c]+S[c-h])/(h^2))]

Richardson Extrapolation

S[x_]=Normal[Series[f[x],{x,c,14}]] (*Longer Taylor Series expansion*)

DS[h_]=Simplify[((S[c+h]-S[c-h])/(2h))] (*Centered Difference Approx.*)

Expand[DS[h]]

Expand[(3^2)DS[(h/3)]]

DS2[h_]=Expand[((DS[h]-(3^2)DS[(h/3)])/(1-(3^2)))]

Continuing Recursively...

DS4[h_]=Expand[((DS2[h]-(3^4)DS2[(h/3)])/(1-(3^4)))]

DS6[h_]=Expand[((DS4[h]-(3^6)DS4[(h/3)])/(1-(3^6)))]

DS8[h_]=Expand[((DS6[h]-(3^8)DS6[(h/3)])/(1-(3^8)))]

DS10[h_]=Simplify[((DS8[h]-(3^10)DS8[(h/3)])/(1-(3^10)))]  (* An O((h^12)) finite difference approx! *)

Romberg Integration

g[x_]:=4 Sqrt[1-(x^2)]

Integrate[g[x],{x,0,1}]

NIntegrate[g[x],{x,0,1},12]

NIntegrate[g[x],{x,0,1},WorkingPrecision->100]